1. <em id="3qmea"><ol id="3qmea"></ol></em>
    2. <em id="3qmea"></em>
      (玩电子) 电子技术学习与研究
      当前位置单片机教程网 >> 基础教程 >> 浏览文章

      24课:动态扫描显示接口电路及程序

      作者:佚名   来源:本站原创   点击数:x  更新时间2007年08月14日   字体

          在单片机系统中动态扫描显示接口是单片机中应用最为广泛的一种显示方式之一其接口电路?#21069;?#25152;有显示器的8个笔划段a-h同名端连在一起而每一个显示器的公共极COM是各自独立地受I/O线控制CPU向字段输出口?#32479;?#23383;形码时所有显示器接收到相同的字形码但究竟是那个显示器亮则取决于COM端而这一端是由I/O控制的所以我们就能自?#33455;?#23450;何时显示哪一位了而所谓动态扫描就是指我们采用分时的办法轮流控制各个显示器的COM端使各个显示器轮流点亮在http://www.15888691.com还有很多关于单片机显示接口的文章大家可以参考一下

         在轮流点亮扫描过程中?#35838;?#26174;示器的点亮时间是极为短暂的约1ms但由于人的视觉暂留现象及发光二极管的余辉效应尽管实际上各位显示器并非同时点亮但只要扫描的速度足够快给人的印象就是一组稳定的显示数据不会有?#20102;小?/p>

         下图所示就是我们的单片机实验板?#31995;?#21160;态扫描接口由89c51的P0口能灌入较大的电流所以我们采用共阳的数码管并且不用限流电阻而只是用两只1N4004进行降压后给数码管供电这里仅用了两只实际上还能扩充它们的公共端则由PNP型三极管8550控制显然如果8550导通则对应的数码管就能亮而如果8550截止则对应的数码管就不可能亮8550是由P2.7P2.6控制的这样我们就能通过控制P27P26达到控制某个数码管亮或灭的目的

      下面的这个单片机程序就是用实验板?#31995;?#25968;码管显示0和1

      FIRST EQU P2.7 ;第一位数码管的位控制

      SECOND EQU P2.6 ;第二位数码管的位控制

      DISPBUFF EQU 5AH ;显示缓冲区为5AH和5BH

      ORG 0000H

      AJMP START

      ORG 30H

      START:

      MOV SP,#5FH ;设置堆栈

      MOV P1,#0FFH

      MOV P0,#0FFH

      MOV P2,#0FFH ;初始化所显示器LED灭

      MOV DISPBUFF,#0 ;第一位显示0

      MOV DISPBUFF+1,#1 ;第二握显示1

      LOOP:

      LCALL DISP ;调用显示程序

      AJMP LOOP

      ;主程序到此结束

      DISP:

      PUSH ACC ;ACC入栈

      PUSH PSW ;PSW入栈

      MOV A,DISPBUFF ;取第一个待显示数

      MOV DPTR,#DISPTAB ;字形表首地址

      MOVC A,@A+DPTR ;取字形码

      MOV P0,A ;将字形码送P0位段口

      CLR FIRST ;开第一位显示器位口

      LCALL DELAY ;延时1毫秒

      SETB FIRST ;关闭第一位显示器开始准备第二位的数据

      MOV A,DISPBUFF+1 ;取显示缓冲区的第二位

      MOV DPTR,#DISPTAB

      MOVC A,@A+DPTR

      MOV P0,A ;将第二个字形码送P0口

      CLR SECOND ;开第二位显示器

      LCALL DELAY ;延时

      SETB SECOND ;关第二位显示

      POP PSW

      POP ACC

      RET

      DELAY: ;延时1毫秒

      PUSH PSW

      SETB RS0

      MOV R7,#50

      D1: MOV R6,#10

      D2: DJNZ R6,$

      DJNZ R7,D1

      POP PSW

      RET

      DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H

      END

      ?#30001;?#38754;的单片机例程中能看出动态扫描显示必须由CPU?#20013;?#22320;调用显示程序才能保证?#20013;中?#30340;显示

         上面的这个程序能实现数字的显示但不太实用为什么呢这里仅是显示两个数字并没有做其他的工作因此两个数码管轮流显示1毫秒没有问题实?#23454;?#24037;作中当然不可能只显示两个数字还是要做其他的事情的这样在二次调用显示程序之间的时间间隔就不一不定了如果时间间隔比较长就会使显示不连续而实?#20351;?#20316;中是很难保证所有工作都能在很短时间内完成的况且这个显示程序也有点“浪费”每个数码管显示?#23478;?#21344;用1个毫秒的时间这在很多合是?#36745;?#35768;的怎么办呢?#35838;?#20204;能借助于定时器定时时间一到产生中断点亮一个数码管然后马上返回这个数码管就会一直亮到下一次定时时间到而不用调用延时程序了这段时间能留给主程序干其他的事到下一次定时时间到则显示下一个数码管这样就很少浪费了

      Counter EQU 59H ;计数器显示程序通过它得知现正显示哪个数码管

      FIRST EQU P2.7 ;第一位数码管的位控制

      SECOND EQU P2.6 ;第二位数码管的位控制

      DISPBUFF EQU 5AH ;显示缓冲区为5AH和5BH

      ORG 0000H

      AJMP START

      ORG 000BH ;定时器T0的入口

      AJMP DISP ;显示程序

      ORG 30H

      START:

      MOV SP,#5FH ;设置堆栈

      MOV P1,#0FFH

      MOV P0,#0FFH

      MOV P2,#0FFH ;初始化所显示器LED灭

      MOV TMOD,#00000001B ;定时器T0工作于模式116位定时/计数模式

      MOV TH0,#HIGH(65536-2000)

      MOV TL0,#LOW(65536-2000)

      SETB TR0

      SETB EA

      SETB ET0

      MOV Counter,#0 ;计数器初始化

      MOV DISPBUFF,#0 ;第一位始终显示0

      MOV A,#0

      LOOP:

      MOV DISPBUFF+1,A ;第二位轮流显示0-9

      INC A

      LCALL DELAY

      CJNE A,#10,LOOP

      MOV A,#0

      AJMP LOOP ;在此中间能按排?#25105;?#31243;序这里仅作示范

      ;主程序到此结束

      DISP: ;定时器T0的中断响应程序

      PUSH ACC ;ACC入栈

      PUSH PSW ;PSW入栈

      MOV TH0,#HIGH(65536-2000) ;定时时间为2000个周期约2170微秒11.0592M

      MOV TL0,#LOW(65536-2000)

      SETB FIRST

      SETB SECOND ;关显示

      MOV A,#DISPBUFF ;显示缓冲区首地址

      ADD A,Counter

      MOV R0,A

      MOV A,@R0 ;根据计数器的值取对应的显示缓冲区的值

      MOV DPTR,#DISPTAB ;字形表首地址

      MOVC A,@A+DPTR ;取字形码

      MOV P0,A ;将字形码送P0位段口

      MOV A,Counter ;取计数器的值

      JZ DISPFIRST ;如果是0则显示第一位

      CLR SECOND ;不然显示第二位

      AJMP DISPNEXT

      DISPFIRST:

      CLR FIRST ;显示第一位

      DISPNEXT:

      INC Counter ;计数器加1

      MOV A,Counter

      DEC A ;如果计数器计到2则让它回0

      DEC A

      JZ RSTCOUNT

      AJMP DISPEXIT

      RSTCOUNT:

      MOV Counter,#0 ;计数器的值只能是0或1

      DISPEXIT:

      POP PSW

      POP ACC

      RETI

      DELAY: ;延时130毫秒

      PUSH PSW

      SETB RS0

      MOV R7,#255

      D1: MOV R6,#255

      D2: NOP

      NOP

      NOP

      NOP

      DJNZ R6,D2

      DJNZ R7,D1

      POP PSW

      RET

      DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H

      END

          ?#30001;?#38754;的单片机程序能看出动态显示和静态显示相比程序稍有点复杂?#36824;?#36825;是值得的这个程序有一定的通用性只要改变端口的值及计数器的值就能显示更多位数了下面给出显示程序的流程图<动态扫描程序框图>

       

       

       

       

       

       

       

      发表评论告诉好友收藏此文关闭窗口

      文章评论

      ຣ11ѡ5app

        
        
        1. <em id="3qmea"><ol id="3qmea"></ol></em>
        2. <em id="3qmea"></em>

            
            
            1. <em id="3qmea"><ol id="3qmea"></ol></em>
            2. <em id="3qmea"></em>